【Excelマクロ】フォルダ内のファイルの一覧と更新時間を取得する

Sub ファイル一覧取得()
    Dim パス As String
    Dim フィルタ As String
    Dim 出力行Index As Long
    
    Range("A4:D1048576").ClearContents 'ファイル一覧をクリアする
    
    パス = Cells(1, 2)
    フィルタ = Cells(2, 2)
    出力行Index = 4
    
    Call ファイル一覧取得Sub(パス, フィルタ, 出力行Index) '
End Sub

Function ファイル一覧取得Sub(ByVal パス As String, ByVal フィルタ As String, ByRef 出力行Index As Long)
    Dim fso As New Scripting.FileSystemObject '
    Dim fileo As File
    Dim foldero As Folder
    Dim ファイル名 As String
    
    If Right(パス, 1) <> "\" Then
        パス = パス + "\"
    End If
    
    ファイル名 = Dir(パス & フィルタ)
    
    Do While ファイル名 <> ""
        Set fileo = fso.GetFile(パス & ファイル名)
        
        ActiveSheet.Hyperlinks.Add Anchor:=Cells(出力行Index, 1), _
            Address:=パス & ファイル名, _
            TextToDisplay:="■" 'リンク
        Cells(出力行Index, 2) = fileo.ParentFolder 'フォルダ名
        Cells(出力行Index, 3) = fileo.Name 'ファイル名
        Cells(出力行Index, 4) = fileo.DateLastModified '更新日付
        
        出力行Index = 出力行Index + 1
        ファイル名 = Dir()
    Loop
    
    'サブフォルダのファイル一覧を取得する
    For Each foldero In fso.GetFolder(パス).SubFolders
        Call ファイル一覧取得Sub(foldero.path, フィルタ, 出力行Index)
    Next

End Function